Hier das AutoIt-Skript, dass die Konvertierung besorgt:

#include <File.au3>
#include <Array.au3>
 
; Definitions
Global $lvlMatch[4] = ["^\s*\d*\.\s*(.*)", "^\s*[a-z]\.\s*(.*)", "^\s*[ivx]*\.\s*(.*)", "^\s*\d*\.\s*(.*)"]
Global $data
_FileReadToArray(@ScriptDir & "\input.txt", $data)
_ArrayDelete($data, 0)
Global $levels[UBound($data)]
 
; Levels herausfinden
For $i = 0 To UBound($data) - 1
	$levels[$i] = -1 ; Default (= no explicit match)
	For $j = UBound($lvlMatch) - 1 To 0 Step -1 ; zu hoch raten im Notfall
		If StringRegExp($data[$i], $lvlMatch[$j], 0) Then
			$levels[$i] = $j
			$data[$i] = StringRegExpReplace($data[$i], $lvlMatch[$j], "\1", 1)
			ContinueLoop 2
		EndIf
	Next
Next
 
; 0/3-Fix
_ArrayInsert($data, 0, "")
_ArrayInsert($levels, 0, -1)
 
For $i = 1 To UBound($data) - 2 ; !
	If (($levels[$i] = 3) And ($levels[$i + 1] = 1)) OR (($levels[$i] = 3) And (StringRegExp($data[$i - 1], "^\s*$", 0))) Then
		$levels[$i] = 0
	EndIf
Next
 
; Fix für Ende
_ArrayAdd($data, "")
_ArrayAdd($levels, 0)
 
; Output generieren
$currLevel = -1
$output = ""
For $i = 0 To UBound($data) - 1
	$newLevel = $levels[$i]
	If $newLevel <> -1 Then
		; runter
		if $newLevel > $currLevel Then
			$output = $output & "\begin{enumerate}" & @CRLF
		EndIf
		; (u.U. mehrfach!) hoch
		while $newLevel < $currLevel
			$output = $output & "\end{enumerate}" & @CRLF
			$currLevel -= 1
		WEnd
 
		$currLevel = $newLevel
	EndIf
 
	If StringRegExp($data[$i], "^\s*$", 0) = 0 Then
		if $levels[$i] = 0 Then
			$output = $output & "\item \hl{" & $data[$i] & "}" & @CRLF
		Else
			$output = $output & "\item " & $data[$i] & @CRLF
		EndIf
	else
		$output = $output & @CRLF
	EndIf
Next
$output &= "\end{enumerate}"
 
; verschönern
$output = StringReplace($output, @CRLF & "\end{enumerate}", "\end{enumerate}" & @CRLF)
 
; schreiben
$fhndl = FileOpen(@ScriptDir & "\output.txt", 2)
FileWrite($fhndl, $output)
FileClose($fhndl)

Das Skript erwartet eine input.txt in seinem Verzeichnis und schmeißt den LaTeX-Schnipsel in der Datei output.txt raus.
Die regulären Ausdrücke zur Erkennung der Aufzählungszeichen lassen sich oben anpassen.

Der Code steht unter der GPLv3-Lizenz.

Viel Spaß damit,
Johannes

Vor allem dank der tatkräftigen Unterstützung von Rasta gibt es eine neue Version des Buches über AutoIt. Vielen herzlichen Dank für das ausführliche und sehr fundierte Lektorat. Weiterer Dank geht an bernd670 für Hinweise zur Verbesserung.

In der neuen Version gibt es neben der Korrektur von viel zu zahlreichen Rechtschreib-, Komma- und Formulierungsfehlern vor allem weit schönere Tabellen und Quellcodelistings. Die Tabellen sind jetzt schön alternierend gefärbt, die Listings farblich deutlich an SciTE angenähert. Wer mir sagen kann, wie ich die Variablen ($xyz) erfassen kann, bekommt eine Erwähnung im Buch .

Gun-Food hat in einem Kommentar zur ersten Veröffentlichung geschrieben, er fände die Titelseite des “Gelben Buches” nicht so schön. Daher rufe ich an dieser Stelle einen Wettbewerb aus, in dem eine neue Titelseite gekürt werden soll. Auch hierfür gibt es eine Erwähnung im Buch. Die Graphik im Format DIN-A4 soll (mindestens) den Titel (AutoIt leicht gemacht), eine Reminiszenz an AutoIt und meinen Namen enthalten. Die Datei muss unter einer passenden CC-Lizenz stehen und als Quelldatei (Ebenen mit änderbarem Text) zur Verfügung gestellt werden.

Die Lizenz des Buches bleibt unverändert (siehe auch im PDF selbst).

Download: AutoIt leicht gemacht – 11. Juli 2009

Viel Erfolg damit,
Johannes

Unter Linux reicht mir ein “sudo shutdown -P +60″, um den Rechner eine Stunde später sicher und komplett abzuschalten.

Aber es gibt ja auch Windows-Nutzer (ich schreibe das gerade unter Windows, weil ich HTML-Ausgaben von Java-Programmen mit IEs testen muss). Denen kann mit AutoIt recht einfach geholfen werden; AutoIt sei Dank:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18

; Screenshot-Funktionen laden
#include <ScreenCapture.au3>
 
; Zeit erfragen und abbrechen, wenn der Nutzer abgebrochen hat
$time = InputBox("Zeit", "In wievielen Minuten soll der Rechner heruntergefahren werden?", "60")
If @error Then Exit
 
; Gewünschte Zeit warten
Sleep($time * 60 * 1000)
 
; Screenshot des ganzen Bildschirmes auf den Desktop ablegen
_ScreenCapture_Capture(@DesktopDir & "\ShutDownShot_Screenshot.jpg")
 
; Letzte Chance
if (MsgBox(4, "Letzte Chance", "Herunterfahren abbrechen?", 15) = 6) Then Exit
 
; Rechner herunterfahren
Shutdown(1 + 8 + 16)

Ein kleiner Mehrwert gegenüber Linux (der sicherlich auch dort mit einem kleinen Bash-Skript einfach erreicht werden könnte): Es wird ein Screenshot angelegt, bevor heruntergefahren wird. So lässt sich vielleicht ohne einen Blick in (hoffentlich überhaupt vorhandene) Log-Dateien feststellen, ob die Operation erfolgreich war.

Der Quelltext steht unter der GPLv3.

Download: ShutDownShot 1.0

Ich habe vor einiger Zeit angefangen, ein Buch über AutoIt zu schreiben. Wichtig waren mir neben der Tatsache, auch informationstechnische Grundlagen zu erklären vor allem folgende Punkte:

• optisch schöner Satz in Buch- und Druckqualität (LaTeX)
• inhaltliche Qualität (Verlinkungen, stilistische Qualität, Rechtschreibung, Grammatik)
• Ausführlichkeit
• große Zahl von Beispielen zur Verdeutlichung

Auf dieser Grundlage sind im Laufe der Zeit bisher 85 Seiten entstanden (einige gehen für das Inhalts- und weitere Verzeichnisse ab). Da ich aber im Moment viel zu viel anderes zu tun habe und zu viele andere Dinge meine Aufmerksamkeit, Zeit und Lust binden, ging es in letzter Zeit nicht voran.

Gestern habe ich den LaTeX-Quellcode aufgeräumt und auf den aktuellen Stand meiner Fähigkeiten gebracht sowie noch einmal sehr grob Korrektur gelesen.

Copyright

Weil mir die inhaltliche Qualität des Buches sehr, sehr am Herzen liegt, möchte ich das Buch nicht frei geben. Vielmehr stelle ich es unter die Lizenz CC-BY-NC-ND. Bitte lest die Lizenz durch, das ist wirklich wichtig. Ganz kurz zusammengefasst, räume ich euch folgende Rechte ein: Ihr dürft das PDF unverändert und unter meiner Namensnennung kostenlos weitergeben. Es ist allerdings untersagt, davon eigene Werke abzuleiten (z.B. eigene Kapitel anzufügen, Links anzubringen usw.). Außerdem dürft ihr für die Weitergabe kein Geld verlangen.

“AutoIt leicht gemacht” steht unter einer Creative Commons Namensnennung-Keine kommerzielle Nutzung-Keine Bearbeitung 3.0 Deutschland Lizenz.

Der zugrunde liegende LaTeX-Quellcode wird nicht veröffentlicht, Menschen meines Vertrauens gewähre ich aber gerne Einblick.

Eine Veröffentlichung (auch in Teilen) auf Wikibooks widerspreche ich (die Optik finde ich grausam, die regt auch nicht dazu an, schöne Texte zu schreiben).

Entwicklung

Die Entwicklung stelle ich mir wie folgt vor: Jeder, der sich berufen fühlt, kann mir Textteile schicken. Aber gleich die Warnung: Ich bin wählerisch, die sprachliche Qualität geht mir über alles. Das ist nichts gegen euch, aber ich will einfach sicherstellen, dass das Buch schön und qualitativ hochwertig wird. Da mir die Zeit fehlt, großflächig Korrektur zu lesen und Texte zu korrigieren, kann ich nur korrekte Texte einbauen (dann aber sehr gerne). Ihr könnt Teile also zunächst von anderen lesen lassen, die Ahnung von der deutschen Sprache haben.

Kleinere Fixes hätte ich zunächst am liebsten als “Search & Replace”-Patterns, die ich einfach ausführen kann (autoit-buch/at\slzm.de).

Wichtig ist noch, nicht gleich drauf los zu schreiben, sondern ein Konzept zu haben, was man vermitteln will in einem Kapitel.

Kommentare

Über jeglichen Kommentar zum Buch freue ich mich .
Ich hoffe, dass es euch den Einstieg in AutoIt erleichtert.

Download

AutoIt leicht gemacht.pdf

Update:

http://web.slzm.de/blog/programmieren/autoit-buch-episode-ii/

Johannes